                             org 7701h          
               bitmap:                            ; prefix the code with bitmap data
7701 0251307209049249        defb 02h,51h,30h,72h,09h,04h,92h,49h
               start:                             ; start = $7709 => BC
7709 58                      ld e, b              ; copy $77 => E
               col:                             
770a 0609                    ld b, 9              ; start each col on the 10th row, immediately
               rotate:                            ; plot an asterisk and its 4 rotations
770c c5                      push bc              ; save BC as it gets destroyed 
770d cdf508                  call 08f5h           ; point HL at (col C, row B)
7710 c1                      pop bc               ; retrieve BC
7711 3617                    ld (hl), 23          ; plot one *
7713 3e12                    ld a, 18             ; load A with rotation constant
7715 90                      sub b                ; A = 18-B
7716 c8                      ret z                ; If col = 0 then exit before plotting bitmap
7717 41                      ld b, c              ; B = C and
7718 4f                      ld c, a              ; C = 18-B => rotate 90º clockwise around (9,9)
7719 cb0b                    rrc e                ; 8-bit rotate E, exit loop every 4 rotations
               check:                           
771b 38ef                    jr c, rotate         ; plot if set / exit loop every 4th time
771d 63                      ld h,e               ; bitmap resides at $7700 + col, load the $77
771e 69                      ld l,c               ; from E and the col from C
771f cb3e                    srl (hl)             ; grab 1 bit from bitmap
7721 10f8                    djnz check           ; use this bit for next row, until we run out
7723 0d                      dec c                ; otherwise, move on to next col
7724 e9                      jp (hl)              ; print the next col and its rotations
               end:                               ; equivalent to jr col
7725
